ActionScript 3.0: Bileşenler (Components) V - Ders -

Bu derste;

DataGrid’leri Kullanma
ActionScript İle DataGrid Oluşturma
Label’ları Kullanma
ActionScript İle Label Oluşturma
List’leri Kullanma
ActionScript İle List Oluşturma
konularına değinilmiştir.

• DataGrid’leri Kullanmak:

DataGrid bileşeni, bir diziden veya harici bir XML dosyasından alınan verileri satır ve sütün halinde göstermek için kullanılır. DataGrid bileşeni yatay ve dikey kaydırma çubukları ile olayları destekleyebilirken sıralamada yapabilmektedir.

Gridlerin renk,font,sınır çizgileri gibi özellikleri değiştirilebilmektedir. İstenirse DataGrid kaydırma çubukları iptal edilebilir. DataGrid klavyeden, "Shift+Up/Down", "Shift+Click", "Ctrl+Click", "Home", "End", "PageUp", "PageDown", "Return/Enter/", "Shift+Enter ", "Shift+Tab", "Tab " ve yön tuşları ile kontrol edilebilir.

DataGrid bileşeni, webmail istemcilerinde, araştırma sayfalarında, veri sıralama uygulamalarında sıkça kullanılan bir bileşendir.

Bir DataGrid bileşeninin Property özelliklerindeki Parametre sekmesinden "allowMultipleSelection", "editable", "headerHeight", "showHeaders", "horizontalLineScrollSize", "horizontalPageScrollSize", "horizontalScrolllPolicy", "resizableColumns", "rowHeight", "verticalLineScrollSize", "verticalPageScrollSize" ve "verticalScrollPolicy" alanları kontrol edilebilir.

ActionScript İle DataGrid Oluşturmak:

DataGrid bileşeni Components panelinden çift tıklanarak kütüphaneye aktarılır. Ayrıca DataGrid’e aktarılacak veri kaynağının da nereden geleceğine karar vermek gerekir. Genellikle veri kaynağı olarak diziler (Array) veya XML kullanılmaktadır. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.


import fl.controls.DataGrid; // DataGrid sınıfı uygulama dahil edildi
import fl.data.DataProvider; // DataProvider sınıfı uygulama dahil edildi
var aDg:DataGrid = new DataGrid(); // DataGrid nesnesi oluşturuldu
addChild(aDg); // DataGrid nesnesi sahneye aktarıldı
aDg.columns = [ "Ad", "Yaş" ];
aDg.setSize(140, 100);
aDg.move(10, 40);
// aDg adlı DataGrid nesnesinin sütün adları,boyutları ve konumu belirlendi
var listem:Array = new Array();
listem.push({Ad:"Tarık", Yaş:6});
listem.push({Ad:"Yıldız", Yaş:19});
listem.push({Ad:"Leyla", Yaş:24});
// Listem adlı verileri barındıran dizi oluşturuldu
aDg.dataProvider = new DataProvider(listem);
// listem adlı dizideki veriler DataGrid'e aktarıldı
aDg.rowCount = aDg.length; // DataGrid satırı sayısı, veri sayısına eşitlendi//Program Ekran Çıktısı:



http://www.mmistanbul.com/media/sharedfiles/content/3A3D67C7EDEBD87895D6A17E81AB1004.jpg







Aşağıdaki kod satırlarında ise DataGrid’e veriler XML kaynağı kullanılarak aktarılıyor.


import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.controls.DataGrid;
import fl.data.DataProvider;

var listem:XML = <liste>
<liste Ad="Tarık" Yaş="6" />
<liste Ad="Yıldız" Yaş="19" />
<liste Ad="Leyla" Yaş="24" />
</liste>;
var adSutun:DataGridColumn = new DataGridColumn("Ad");
adSutun.headerText = "Ad";
adSutun.width = 120;
var yasSutun:DataGridColumn = new DataGridColumn("Yaş");
yasSutun.headerText = "Yaş";
yasSutun.width = 60;

var veriSagla:DataProvider = new DataProvider(listem);

var aDg:DataGrid = new DataGrid();
addChild(aDg);
aDg.setSize(140, 100);
aDg.move(10, 40);
aDg.columns = [adSutun, yasSutun];
aDg.dataProvider = veriSagla;
aDg.rowCount = aDg.length;• Label’ları Kullanmak:

Label (etiket) bileşeni, diğer bileşen veya uygulamaları belirtmek için kullanılan tek satırlı bir metindir. Label’ların büyüklüğü ve hizalanması ile ilgili özellikleri ayarlanabilmektedir. Ayrıca HTML format yapısı (tag) Label’lara aktarılarak daha fazla biçimsel ayar yapılabilmektedir. Öte yandan, Label’lerin sınır (border) özelliği, focus özelliği ve herhangi bir olayı bildirmesi gibi özellikleri bulunmamaktadır. Bir Label bileşeninin Property özelliklerindeki Parametre sekmesinden "autoSize", "condenseWhite", "selectable"," text" ve "wordWrap" alanları kontrol edilebilir.

ActionScript İle Label Oluşturmak:

Label ve ColorPicker bileşenleri Components panelinden çift tıklanarak kütüphaneye aktarılır. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.


import fl.controls.Label; // Label sınıfı uygulama dahil edildi
import fl.controls.ColorPicker; // ColorPicker sınıfı uygulama dahil edildi
var etiket:Label = new Label(); // Label nesnesi oluşturuldu
var renkKutusu:ColorPicker = new ColorPicker(); // ColorPicker nesnesi oluşturuldu
addChild(etiket); // Label nesnesi sahneye taşındı
addChild(renkKutusu); // ColorPicker nesnesi sahneye taşındı
etiket.htmlText = '<font face="Arial" color="#008308" size="17">Renkler:</font>';
// etiket adlı Label nesnesine htmlText özelliği verilerek HTML tagları ile biçimlendirildi
etiket.y = 130;
etiket.width = 100;
etiket.height = 80;
renkKutusu.x = 200;
renkKutusu.y = 130;
// etiket ve renkKutusu nesnelerinin konumu ve boyutları ayarlandı
// Program Ekran Çıktısı



http://www.mmistanbul.com/media/sharedfiles/content/06CE391D5EBED5C1ECE8D367DE025867.jpg





• List’leri Kullanmak:

List bileşeni, scroll özelliği olan tekli veya çoklu seçim listesi sunan bir bileşendir. List bileşeni ayrıca diğer bileşenleri içeren grafikleri de gösterebilmektedir. "List.addItem()" ve "List.addItemAt()" metotları ile listeye öğe eklenebilirken Property özelliklerindeki Parametre sekmesinden "Value" diyalog kutusu ile de liste öğeleri eklenebilmektedir. Liste öğeleri indeks numarısını 0’dan başlayarak alır. 0 en üste olan liste elemanını temsil eder. Listeye herhangi bir öğe eklerken veya çıkarırken bu indeks numaralarına ihtiyaç vardır. List bileşeni klavyeden, "Home", "Page Down", "Page Up", "Shift", "Control", yukarı ve aşağı ok tuşları ile alfanumerik tuşlarla kontrol edilebilir.

Bir List bileşeninin Property özelliklerindeki Parametre sekmesinden "allowMultipleSelection", "dataProvider", "horizontalLineScrollSize", "horizontalPageScrollSize", "horizontalScrollPolicy", "multipleSelection", "verticalLineScrollSize", "verticalPageScrollSize" ve "verticalScrollPolicy " alanları kontrol edilebilir.

ActionScript İle List Oluşturmak:

List bileşeni Components panelinden çift tıklanarak kütüphaneye aktarılır. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.



import fl.controls.TextArea; // TextArea sınıfı uygulama dahil edildi
import fl.controls.List; // List sınıfı uygulama dahil edildi
var aTa:TextArea = new TextArea(); // TextArea nesnesi oluşturuldu
var liste:List = new List(); // List nesnesi oluşturuldu
liste.addItem({label:"Tarık", data:"Yaş:6"});
liste.addItem({label:"Leyla", data:"Yaş:24"});
liste.addItem({label:"Yıldız", data:"Yaş:19"});
liste.addItem({label:"Suat", data:"Yaş:35"});
// liste adlı List nesnesine veriler eklendi
liste.setSize(160, 80); // liste adlı List nesnesinin boyutu ayarlandı
liste.move(200,200); // liste adlı List nesnesinin konumu ayarlandı
addChild(liste); // liste adlı List nesnesi sahneye aktarıldı
addChild(aTa); // aTa adlı TextArea nesnesi sahneye aktarıldı
aTa.move(370,200); // aTa adlı TextArea nesnesinin konumu ayarlandı
liste.addEventListener(Event.CHANGE, sec);
function sec(event:Event):void {
aTa.text=event.target.selectedItem.data;
// aTa adlı TextArea nesnesi, liste adlı List nesnesindeki verilere bağlandı
}
// Programın Ekran Çıktısı





http://www.mmistanbul.com/media/sharedfiles/content/15DFCD9A520AE55BDBDC0A210E561ED2.jpg

Güzelmiş Okumadım şimdi okuyacağım